home *** CD-ROM | disk | FTP | other *** search
/ Aminet 21 / Aminet 21 (1997)(GTI - Schatztruhe)[!][Oct 1997].iso / Aminet / comm / mail / CfgYamDE.lha / configyam11german / ConfigYam.rexx < prev    next >
OS/2 REXX Batch file  |  1997-08-14  |  28KB  |  826 lines
  1. /******************************************************************************/
  2. /*                                                                            */
  3. /*                          ConfigYam.rexx                                    */
  4. /*                 Copyright ©1997 by Dick Whiting                            */
  5. /*                                                                            */
  6. /*----------------------------------------------------------------------------*/
  7. /*                 This version requires MuiRexx 3.0a+                        */
  8. /*----------------------------------------------------------------------------*/
  9. /* This allows you to easily modify the order of folders in the Yam config,   */
  10. /* rename the actual mail folders, and edit other entries.                    */
  11. /*                                                                            */
  12. /*                    !!KNOW WHAT YOU ARE DOING!!!                            */
  13. /*                                                                            */
  14. /* Turn on 'help bubbles' and USE them!!                                      */
  15. /*                                                                            */
  16. /*----------------------------------------------------------------------------*/
  17. /* Select the configuration file, use drag-and-drop to reorder the lists,     */
  18. /* edit as allowed.                                                           */
  19. /*----------------------------------------------------------------------------*/
  20. /*                                                                            */
  21. /* Standard Disclaimer: I wrote it, it works for me, I don't guarantee        */
  22. /* that it will do anything productive for anyone else, etc. etc. ;-)         */
  23. /*                                                                            */
  24. /*HOWEVER, if you DO find a use for it: I homeschool my kids and they         */
  25. /*would love a postcard from where EVER you live.                             */
  26. /*                                                                            */
  27. /*Instant GEOGRAPHY lesson;)                                                  */
  28. /*                                                                            */
  29. /*                                                                            */
  30. /*POSTCARDS:    Dick Whiting                                                  */
  31. /*              28590 S. Beavercreek Rd.                                      */
  32. /*              Mulino, Oregon 97042                                          */
  33. /*              USA                                                           */
  34. /*                                                                            */
  35. /*----------------------------------------------------------------------------*/
  36. /*                                                                            */
  37. /*               Address Bug Reports or Comments to:                          */
  38. /*                Dick Whiting <dwhiting@europa.com>                          */
  39. /*                         13 August 1997                                     */
  40. /*                                                                            */
  41. /******************************************************************************/
  42. /*
  43. $VER: 1.1 Copyright ©1997 by Dick Whiting
  44. $AUTHOR: Dick Whiting
  45. $DESCRIPTION: Quick config changes for Yam.
  46. */
  47.  
  48. options results
  49. options failat 21
  50.  
  51. parse arg mainparm subparm
  52.  
  53. /**************************************************************************/
  54. /*                         Initialize Variables                           */
  55. /**************************************************************************/
  56. Call MUIvars                                /* go define vars for MUI use */
  57. Call CYvars                                 /* various values used in CY  */
  58. Call Helpvars                               /* pointers into HELP guide   */
  59. Call Localize                               /* vars for localizing strings*/
  60. Call Builtvars                              /* built using previous values*/
  61.  
  62. Address CONFIGYAM
  63.  
  64. Select
  65.    when mainparm='' then do
  66.       Call CheckDup
  67.       Call BuildWindow
  68.    end
  69.    when mainparm='LOAD' then do
  70.       Call LoadConfig
  71.    end
  72.    when mainparm='DELETEFLD' then do
  73.       Call DeleteFlds
  74.    end
  75.    when mainparm='EDITFLD' then do
  76.       Call EditFlds
  77.    end
  78.    when mainparm='HIDEFLD' then do
  79.       Call HideFldList 
  80.    end
  81.    when mainparm='INSERTFLD' then do
  82.       Call InsertFlds
  83.    end
  84.    when mainparm='STOREFLD' then do
  85.       Call StoreFlds
  86.    end
  87.    when mainparm='DELETEMAIN' then do
  88.       Call DeleteMain
  89.    end
  90.    when mainparm='EDITMAIN' then do
  91.       Call EditMain
  92.    end
  93.    when mainparm='HIDEMAIN' then do
  94.       Call HideMainList 
  95.    end
  96.    when mainparm='INSERTMAIN' then do
  97.       Call InsertMain
  98.    end
  99.    when mainparm='STOREMAIN' then do
  100.       Call StoreMain
  101.    end
  102.    when mainparm='SAVE' then do
  103.       Call SaveConfig
  104.    end
  105.    when mainparm='SAVEAS' then do
  106.       Call GetFileName
  107.       Call SaveConfig
  108.    end
  109.    when mainparm='QUIT' then do
  110.       'quit' 
  111.    end
  112.    otherwise do
  113.       errmsg=_text._badparm
  114.       Call ErrorMsg
  115.    end
  116. end 
  117.  
  118. exit
  119.  
  120. /**************************************************************************/
  121. /*                  Load the config file into the arrays                  */
  122. /**************************************************************************/
  123. LoadConfig:   
  124.  
  125.    popasl ID CYCFG
  126.    mfile=result
  127.  
  128.    infotext=_text._loadfile
  129.    infobuttons=''
  130.    showbusy=TRUE
  131.    Call InfoWindow
  132.  
  133.    method ID CYALL MUIM_List_Clear
  134.    method ID CYFLD MUIM_List_Clear
  135.  
  136.    fldfound=FALSE
  137.  
  138.    if open('IN',mfile,'R') then do
  139.       do until eof('IN')
  140.          linein=readln('IN')
  141.          Select
  142.             when upper(substr(linein,1,6))='FOLDER' then do
  143.                oldnum=word(linein,1)
  144.                oldnum=substr(oldnum,7)
  145.                parse var linein folder '=' linein
  146.                linein=translate(linein,',',';')
  147.                linein=linein||','||oldnum
  148.                list ID CYFLD INSERT POS MUIV_List_Insert_Bottom STRING linein
  149.                if ~fldfound then do
  150.                   list ID CYALL INSERT POS MUIV_List_Insert_Bottom STRING '='_text._fldheader
  151.                   fldfound=TRUE
  152.                end
  153.             end
  154.             otherwise do
  155.                list ID CYALL INSERT POS MUIV_List_Insert_Bottom STRING '='linein
  156.             end
  157.          end
  158.       end
  159.       foo=close('IN')
  160.       window ID CYINF close
  161.    end
  162.    else do
  163.       errmsg=_text._badfile
  164.       Call ErrorMsg
  165.       exit     
  166.    end
  167.  
  168. Return
  169.  
  170. /**************************************************************************/
  171. /*                        Delete line from Main Configuration             */
  172. /**************************************************************************/
  173. DeleteMain:
  174.  
  175.    list ID CYALL ATTRS MUIA_List_Active
  176.    mainpos=result
  177.    list ID CYALL POS mainpos
  178.    oldline=result
  179.    if oldline=_text._fldheader | pos(_text._yamheader,oldline)>0 then do
  180.       errmsg=_text._protected  
  181.       Call ErrorMsg
  182.       exit
  183.    end
  184.  
  185.    list ID CYALL REMOVE POS mainpos
  186.     
  187. Return
  188.  
  189. /**************************************************************************/
  190. /*                        Edit Main Configuration                         */
  191. /**************************************************************************/
  192. EditMain:
  193.  
  194.    list ID CYALL ATTRS MUIA_List_Active
  195.    mainpos=result
  196.    list ID CYALL POS mainpos
  197.    oldline=result
  198.    if oldline=_text._fldheader | pos(_text._yamheader,oldline)>0 then do
  199.       errmsg=_text._protected  
  200.       Call ErrorMsg
  201.       exit
  202.    end
  203.  
  204.    string ID CYMCS CONTENT oldline
  205.     
  206. Return
  207.  
  208. /**************************************************************************/
  209. /*                        Insert New folder in Config                     */
  210. /**************************************************************************/
  211. InsertMain:
  212.  
  213.  
  214.    list ID CYALL ATTRS MUIA_List_Active
  215.    mainpos=result+1
  216.  
  217.    string ID CYMCS 
  218.    mainentry=result
  219.  
  220.    list ID CYALL INSERT POS mainpos STRING '='mainentry
  221.  
  222. Return
  223.  
  224. /**************************************************************************/
  225. /*                        Store Main Configuration Entry                  */
  226. /**************************************************************************/
  227. StoreMain:
  228.  
  229.    string ID CYMCS
  230.    mainentry=result
  231.    list ID CYALL ATTRS MUIA_List_Active
  232.    mainpos=result
  233.    list ID CYALL POS mainpos STRING '='mainentry  
  234.  
  235. Return
  236.  
  237. /**************************************************************************/
  238. /*                        Delete a folder from the Config                 */
  239. /**************************************************************************/
  240. DeleteFlds:
  241.  
  242.    list ID CYFLD ATTRS MUIA_List_Active
  243.    fldpos=result
  244.    if fldpos<4 then do
  245.       errmsg=_text._baddelete
  246.       Call ErrorMsg
  247.    end
  248.    else do
  249.       list ID CYFLD REMOVE POS fldpos
  250.    end
  251.  
  252. Return
  253.  
  254. /**************************************************************************/
  255. /*                        Edit Foldre Entry                               */
  256. /**************************************************************************/
  257. EditFlds:
  258.  
  259.    list ID CYFLD ATTRS MUIA_List_Active
  260.    fldpos=result
  261.    list ID CYFLD POS fldpos
  262.    oldline=result
  263.    parse var oldline ftype ',' fsort ',' ffile ',' fname ',' oldnum
  264.    string ID CYFL1 CONTENT fsort
  265.    string ID CYFL2 CONTENT ffile
  266.    string ID CYFL3 CONTENT fname
  267.  
  268. Return
  269.  
  270. /**************************************************************************/
  271. /*                        Insert New folder in Config                     */
  272. /**************************************************************************/
  273. InsertFlds:
  274.  
  275.    ftype=2
  276.  
  277.    list ID CYFLD ATTRS MUIA_List_Entries
  278.    oldnum=result+1
  279.  
  280.    list ID CYFLD ATTRS MUIA_List_Active
  281.    fldpos=result+1
  282.  
  283.    if fldpos<4 then fldpos=4       /* force after system folders */
  284.  
  285.    string ID CYFL1 
  286.    fsort=result
  287.  
  288.    string ID CYFL2 
  289.    ffile=result
  290.  
  291.    string ID CYFL3 
  292.    fname=result
  293.  
  294.    newline=ftype||comma||fsort||comma||ffile||comma||fname
  295.  
  296.    list ID CYFLD INSERT POS fldpos STRING newline
  297.  
  298. StoreFoldEnd:
  299.  
  300. Return
  301.  
  302. /**************************************************************************/
  303. /*                        Store Folder Entry                              */
  304. /**************************************************************************/
  305. StoreFlds:
  306.  
  307.    list ID CYFLD ATTRS MUIA_List_Active
  308.    fldpos=result
  309.    list ID CYFLD POS fldpos
  310.    oldline=result
  311.    parse var oldline ftype ',' fsort ',' ffile ',' fname ',' oldnum
  312.  
  313.    select
  314.       when subparm=1 then do
  315.          string ID CYFL1 
  316.          newfsort=result
  317.          if newfsort>=0 & newfsort<=3 then fsort=newfsort
  318.       end
  319.       when subparm=2 then do
  320.          popasl ID CYMDR
  321.          maildir=strip(result,'B')
  322.          if maildir='' | maildir='RESULT' | ~exists(maildir) then do
  323.              errmsg=_text._badmaildir
  324.              Call ErrorMsg
  325.              exit
  326.          end
  327.          else do
  328.             lastchar=substr(maildir,length(maildir),1)
  329.             if verify(':/',lastchar,'MATCH')=0 then maildir=maildir||'/'
  330.          end
  331.          string ID CYFL2 
  332.          newffile=result
  333.  
  334.          if pos(':',ffile)=0 then tffile=maildir||ffile
  335.                              else tffile=ffile
  336.          if pos(':',newffile)=0 then tnewffile=maildir||newffile
  337.                                 else tnewffile=newffile
  338.          select 
  339.             when strip(newffile,'B')='' then nop
  340.             when exists(tnewffile) & upper(tffile)~=upper(tnewffile) then do
  341.                errmsg=_text._newexists
  342.                Call ErrorMsg
  343.                exit
  344.             end
  345.             when strip(ffile,'B')='' & ~exists(tnewffile) then ffile=tnewffile
  346.             when ~exists(tffile) & ~exists(tnewffile) then ffile=tnewffile
  347.             when exists(tffile) & upper(newffile)~=upper(ffile)  then do
  348.                request ID CYREN GADGETS _text._renreq STRING _title._rename
  349.                if result=1 then do
  350.                   address command 'Rename >nil: 'tffile tnewffile ' QUIET'
  351.                   if rc=0 then do
  352.                      ffile=tnewffile
  353.                   end
  354.                   else do 
  355.                      errmsg=_text._badrename||rc
  356.                      Call ErrorMsg
  357.                      exit
  358.                   end 
  359.                end
  360.                else do
  361.                   signal StoreFoldEnd
  362.                end
  363.             end
  364.             otherwise nop
  365.          end   
  366.       end /* end of when subparm=2 condition */
  367.  
  368.       when subparm=3 then do
  369.          string ID CYFL3 
  370.          fname=result
  371.       end
  372.       otherwise nop
  373.    end
  374.  
  375.    newline=ftype||comma||fsort||comma||ffile||comma||fname
  376.    list ID CYFLD ATTRS MUIA_List_Active
  377.    fldpos=result
  378.    list ID CYFLD POS fldpos STRING newline
  379.  
  380. StoreFoldEnd:
  381.  
  382. Return
  383.  
  384. /**************************************************************************/
  385. /*                        Get Filename for SAVEAS                         */
  386. /**************************************************************************/
  387. GetFileName:
  388.  
  389.    popasl ID CYCFG
  390.    configfile=result
  391.  
  392.    savfile=''
  393.    select
  394.       when lastpos('/',configfile)>0 then do
  395.          savdir=substr(configfile,1,lastpos('/',configfile)-1)
  396.       end
  397.       when lastpos(':',configfile)>0 then do
  398.          savdir=substr(configfile,1,lastpos(':',configfile))
  399.       end
  400.       otherwise do
  401.          savdir="""T:"""
  402.       end
  403.    end
  404.  
  405.    aslrequest ID CYWIN TITLE _title._asl,
  406.               ATTRS ASLFR_InitialDrawer savdir ASLFR_InitialFile savfile 
  407.  
  408.    if rc = 0 then do
  409.       configfile=result
  410.       popasl ID CYCFG content configfile
  411.    end
  412.    else do
  413.       exit
  414.    end
  415.  
  416. Return
  417.  
  418. /**************************************************************************/
  419. /*                         Save Configuration                             */
  420. /**************************************************************************/
  421. SaveConfig:
  422.  
  423.    popasl ID CYCFG
  424.    configfile=result
  425.  
  426.    if ~open('OUT',configfile,'W') then do
  427.       errmsg=_text._badsavefile
  428.       Call ErrorMsg
  429.       exit
  430.    end
  431.  
  432.    infotext=_text._savingfile
  433.    infobuttons=''
  434.    showbusy=TRUE
  435.    Call InfoWindow
  436.  
  437.    list ID CYALL ATTRS MUIA_List_Entries
  438.    acnt=result
  439.  
  440.    list ID CYFLD ATTRS MUIA_List_Entries
  441.    ocnt=result
  442.  
  443.    do i=0 to acnt-1
  444.       list ID CYALL POS i
  445.       lineout=result
  446.       select
  447.          when lineout=_text._fldheader then do
  448.             do j=0 to ocnt-1
  449.                list ID CYFLD POS j
  450.                lineout=result
  451.                parse var lineout ftype ',' fsort ',' ffile ',' fname ',' oldnum
  452.                lineout=ftype||';'||fsort||';'||ffile||';'||fname
  453.                fldnum='Folder'||j
  454.                lineout=left(fldnum,16,' ')||'='||lineout
  455.                foo=writeln('OUT',lineout)
  456.             end
  457.          end
  458.          otherwise do
  459.             foo=writeln('OUT',lineout)
  460.          end
  461.       end
  462.    end
  463.  
  464.    foo=close('OUT')
  465.    window ID CYINF close
  466.  
  467. Return
  468.  
  469. /**************************************************************************/
  470. /*              Hide the Main Configuration list, show folder list.       */
  471. /**************************************************************************/
  472. HideMainList:
  473.  
  474.    group ID CYFLG ATTRS MUIA_ShowMe TRUE
  475.    group ID CYMCC ATTRS MUIA_ShowMe FALSE 
  476.  
  477. Return
  478.  
  479. /**************************************************************************/
  480. /*              Hide the folder list, show the main configuration list.   */
  481. /**************************************************************************/
  482. HideFldList:
  483.  
  484.    group ID CYMCC ATTRS MUIA_ShowMe TRUE
  485.    group ID CYFLG ATTRS MUIA_ShowMe FALSE
  486.  
  487. Return
  488.  
  489. /**************************************************************************/
  490. /*              Make sure there isn't one running already.                */
  491. /**************************************************************************/
  492. CheckDup:
  493.  
  494.    list ID CYALL ATTRS MUIA_List_Entries
  495.    if result~='RESULT' then do
  496.       errmsg=_text._secondrun
  497.       Call ErrorMsg
  498.       exit
  499.    end
  500.  
  501. Return
  502.  
  503. /******************************************************************************/
  504. /*  Display ERROR message and EXIT.                                           */
  505. /******************************************************************************/
  506. ErrorMsg:
  507.  
  508.    window ID CYERR CLOSE
  509.  
  510.    request ID ERRM GADGETS  _text._ok errmsg
  511.  
  512.    exit
  513.  
  514. Return
  515.  
  516. /******************************************************************************/
  517. /*  Display the mail in a list window.                                        */
  518. /******************************************************************************/
  519. BuildWindow:
  520.  
  521.    window ID CYWIN TITLE _title._main,        
  522.           COMMAND '"ConfigYam.rexx QUIT"'
  523.  
  524.         group
  525.          group HORIZ 
  526.                 popasl ID CYCFG HELP help.CYCFG CONTENT Yconfig
  527.                 popasl ID CYMDR HELP help.CYMDR CONTENT maildir
  528.             button ID CYPR0 COMMAND '"ConfigYam.rexx LOAD"',
  529.                     HELP help.CYPR0,
  530.                 ATTRS MUIA_HorizWeight 20,
  531.                      LABEL _label._CYPR0
  532.             button ID CYPR3 HELP help.CYPR3,
  533.                 ATTRS MUIA_HorizWeight 20,
  534.                 LABEL _label._CYPR3
  535.          endgroup
  536.          group ID CYMCC 
  537.             list ID CYALL HELP help.CYALL,
  538.                  COMMAND '"ConfigYam.rexx EDITMAIN"'
  539.             group HORIZ 
  540.                string ID CYMCS HELP help.CYMCS,
  541.                     COMMAND '"ConfigYam.rexx STOREMAIN"'
  542.                button ID CYMCZ HELP help.CYMCZ,
  543.                    COMMAND '"ConfigYam.rexx DELETEMAIN"',
  544.                    ATTRS MUIA_HorizWeight 20,
  545.                          LABEL _label._CYMCZ
  546.                button ID CYMCI HELP help.CYMCI,
  547.                    COMMAND '"ConfigYam.rexx INSERTMAIN"',
  548.                    ATTRS MUIA_HorizWeight 20,
  549.                          LABEL _label._CYMCI
  550.                button ID CYMCX HELP help.CYMCX,
  551.                    ATTRS MUIA_HorizWeight 10,
  552.                          LABEL _label._CYMCX
  553.             endgroup
  554.          endgroup
  555.          group ID CYFLG
  556.             list ID CYFLD HELP help.CYFLD,
  557.                  ATTRS MUIA_Listview_DragType MUIV_Listview_DragType_Immediate, 
  558.                     MUIA_List_ShowDropMarks TRUE,  
  559.                     MUIA_List_DragSortable TRUE,
  560.                     MUIA_Dropable TRUE,
  561.                     MUIA_List_Format """WEIGHT=0 MAXWIDTH=0 MINWIDTH=0,BAR,BAR,,WEIGHT=0 MAXWIDTH=0 MINWIDTH=0""" 
  562.             group HORIZ
  563.                string ID CYFL1 HELP help.CYFL1,
  564.                    COMMAND '"ConfigYam.rexx STOREFLD 1"',
  565.                    ATTRS MUIA_HorizWeight 10 MUIA_String_Accept sortnums
  566.                string ID CYFL2 HELP help.CYFL2,
  567.                    COMMAND '"ConfigYam.rexx STOREFLD 2"',
  568.                    ATTRS MUIA_HorizWeight 100 
  569.                string ID CYFL3 HELP help.CYFL3,
  570.                    COMMAND '"ConfigYam.rexx STOREFLD 3"',
  571.                    ATTRS MUIA_HorizWeight 100
  572.                button ID CYFLZ HELP help.CYFLZ,
  573.                    COMMAND '"ConfigYam.rexx DELETEFLD"',
  574.                    ATTRS MUIA_HorizWeight 20,
  575.                          LABEL _label._CYFLZ
  576.                button ID CYFLI HELP help.CYFLI,
  577.                    COMMAND '"ConfigYam.rexx INSERTFLD"',
  578.                    ATTRS MUIA_HorizWeight 20,
  579.                          LABEL _label._CYFLI
  580.                button ID CYFLX HELP help.CYFLX,
  581.                    ATTRS MUIA_HorizWeight 20,
  582.                          LABEL _label._CYFLX
  583.             endgroup
  584.          endgroup
  585.         endgroup
  586.       group HORIZ 
  587.          button ID CYPR1 COMMAND '"ConfigYam.rexx SAVE"',
  588.                     HELP help.CYPR1,
  589.                      LABEL _label._CYPR1
  590.          button ID CYPR2 COMMAND '"ConfigYam.rexx SAVEAS"',  
  591.                    HELP help.CYPR2,
  592.                 LABEL _label._CYPR2                            
  593.          space
  594.          button ID CYPRQ COMMAND '"ConfigYam.rexx QUIT"',
  595.                     HELP help.CYPRQ,
  596.                      LABEL _label._CYPRQ
  597.       endgroup
  598.  
  599.    endwindow
  600.  
  601.    callhook ID CYPR3 PRESS PORT INLINE,
  602.       COMMAND """options results;
  603.                  Address CONFIGYAM;
  604.                  group ID CYFLG ATTRS " MUIA_ShowMe TRUE";
  605.                  group ID CYMCC ATTRS " MUIA_ShowMe TRUE";"""
  606.  
  607.    callhook ID CYMCX PRESS PORT INLINE,
  608.       COMMAND """options results;
  609.                  Address CONFIGYAM;
  610.                  group ID CYFLG ATTRS " MUIA_ShowMe TRUE";
  611.                  group ID CYMCC ATTRS " MUIA_ShowMe FALSE";"""
  612.  
  613.    callhook ID CYFLX PRESS PORT INLINE,
  614.       COMMAND """options results;
  615.                  Address CONFIGYAM;
  616.                  group ID CYMCC ATTRS " MUIA_ShowMe TRUE";
  617.                  group ID CYFLG ATTRS " MUIA_ShowMe FALSE";"""
  618.  
  619.    callhook ID CYFLD PRESS COMMAND '"ConfigYam.rexx EDITFLD"'
  620.        
  621. Return
  622.  
  623.  
  624. /******************************************************************************/
  625. /*  Simple information/error message window.                                  */
  626. /******************************************************************************/
  627. InfoWindow:
  628.  
  629.    window ID CYINF TITLE _title._info 
  630.  
  631.       group 
  632.          group 
  633.             text ID STEXT HELP help.STEXT LABEL infotext
  634.          endgroup
  635.          if showbusy then do
  636.             group
  637.                object CLASS '"Busy.mcc"' ATTRS MUIA_VertWeight 25
  638.             endgroup
  639.          end
  640.          if infobuttons ~='' then do
  641.             group HORIZ
  642.                group 
  643.                   space HORIZ 
  644.                endgroup
  645.                group 
  646.                   radio ID SQUIT HELP help.SQUIT LABELS infobuttons
  647.                endgroup
  648.                group 
  649.                   space HORIZ 
  650.                endgroup
  651.             endgroup
  652.          end
  653.          else do
  654.             group 
  655.                space HORIZ 100
  656.             endgroup
  657.          end
  658.       endgroup
  659.    endwindow
  660.  
  661. Return
  662.  
  663. /******************************************************************************/
  664. /*                      MUIREXX TAGS & VARIABLES                              */
  665. /******************************************************************************/
  666. Muivars:
  667.  
  668. MUIA_Disabled =             0x80423661
  669. MUIA_Draggable =            0x80420b6e 
  670. MUIA_Dropable =             0x8042fbce 
  671. MUIA_HorizWeight =          0x80426db9
  672. MUIA_List_Active =          0x8042391c 
  673. MUIA_List_DragSortable =    0x80426099
  674. MUIA_List_Format =          0x80423c0a 
  675. MUIA_List_Entries =         0x80421654 
  676. MUIA_List_Quiet =           0x8042d8c7
  677. MUIA_List_ShowDropMarks =   0x8042c6f3 
  678. MUIA_List_Visible =         0x8042191f
  679. MUIA_Listview_DragType =    0x80425cd3
  680. MUIA_Listview_MultiSelect = 0x80427e08
  681. MUIA_Selected =             0x8042654b
  682. MUIA_ShowMe =               0x80429ba8
  683. MUIA_String_Accept =        0x8042e3e1
  684. MUIA_VertWeight =           0x804298d0 
  685. MUIA_Weight =               0x80421d1f 
  686. MUIA_Window_DepthGadget  =  0x80421923
  687. MUIA_Window_PublicScreen =  0x804278e4
  688.  
  689. ASLFR_InitialFile =         0x80080008
  690. ASLFR_InitialDrawer =       0x80080009
  691.  
  692. MUIM_List_Clear =           0x8042ad89
  693. MUIM_List_Select =          0x804252d8 
  694.  
  695. TRUE=1
  696. FALSE=0
  697.  
  698. MUIV_List_Insert_Bottom = -3
  699. MUIV_List_Select_Off = 0
  700. MUIV_List_Select_On = 1
  701. MUIV_Listview_DragType_Immediate = 1
  702. MUIV_Listview_MultiSelect_Shifted = 2
  703.  
  704. Return
  705.  
  706. /**************************************************************************/
  707. /*           Various values used throughout the various routines          */
  708. /**************************************************************************/
  709. CYvars:
  710.  
  711. missing='.'
  712. comma=','
  713. tab='09'x                                   /* tab character              */
  714. sortnums='"=0123"'                          /* valid sort numbers         */
  715. bo='\033b'                                  /* print control BOLD         */
  716. bc='\033b\033c'                             /* print control BOLD CENTER  */
  717.  
  718. yconfig="Yam:.config"
  719. maildir="Yam:"
  720.  
  721. _text._fldheader="ConfigYam..Insert FOLDERS here"
  722. _text._yamheader="YAM Configuration"
  723.  
  724. Return
  725.  
  726. /**************************************************************************/
  727. /*    Messages, text, etc. constructed using previously defined values    */
  728. /**************************************************************************/
  729. Builtvars:
  730. _title._CYALL='"'||bc||_label._cyall'"'
  731. _title._cyfld='"'||bc||_label._cyfld'"'
  732. _text._renreq='"'||_text._ok||'|'||_text._cancel'"'
  733.  
  734. Return
  735.  
  736. /**************************************************************************/
  737. /*               Pointers into the YamTools.guide documentation           */
  738. /**************************************************************************/
  739. Helpvars:
  740.  
  741. Return
  742.  
  743. /**************************************************************************/
  744. /*       Mui Gadgets, text, msgs, etc. used in YamTools                   */
  745. /**************************************************************************/
  746. Localize:
  747.  
  748. /*********************************/
  749. /* Miscellaneous info strings    */
  750. /*********************************/
  751. _title._main="""ConfigYam v1.1"""           /* main screen title          */
  752. _title._info="""ConfigYam Info"""           /* default title on infomsg   */
  753. _title._asl="""Wähle Datei"""               /* title for ASL requester    */
  754. _title._rename="Ordner umbenennen?"         /* title for ASL requester    */
  755.  
  756. _text._ok="Ok"                              /* various OK buttons         */
  757. _text._cancel="Abbruch"                     /* LABEL for CANCEL button    */
  758.  
  759. _label._cypr0="Lade"                        /* label for LOAD button      */
  760. _label._cypr1="Speichern"                   /* label for SAVE  button     */
  761. _label._cypr2="Speichern als"               /* label for SAVEAS button    */
  762. _label._cyprq="Quit"                        /* label for QUIT  button     */
  763. _label._cypr3="Zeige"
  764. _label._cyfli="Einfügen"
  765. _label._cyflx="Verstecken"
  766. _label._cyflz="Löschen"
  767. _label._cymci="Einfügen"
  768. _label._cymcx="Verstecken"
  769. _label._cymcz="Löschen"
  770.  
  771. _text._savingfile="Speicher Konfiguration Datei..." /* saving file message   */
  772. _text._loadfile="Bereite Konfiguration Datei vor..." /* preparing file msg   */
  773.  
  774. /*********************************/
  775. /* Various error conditions      */
  776. /*********************************/
  777.  
  778. _text._baddelete="Du kannst keine System Ordner löschen"
  779. _text._badfile="Kann Konfiguration datei nicht öffnen"
  780. _text._badmaildir="Wähle gültiges Post Verzeichnis"
  781. _text._badparm="Unbekannte Werte in ConfigYam:"
  782. _text._badrename="Umbennen failed..Return Code="
  783. _text._badsavefile="Kann output datei nicht öffnen"
  784. _text._newexists="Neuer Dateiname gibt es bereits"
  785. _text._protected ="Kann diese Linie nicht bearbeiten"
  786. _text._secondrun="ConfigYam wurde schon gestartet"  /* second run */
  787.  
  788. /**************************************************************************/
  789. /*           Help Messages to display with MUI bubble facility.           */
  790. /*                                                                        */
  791. /* Format is simple: help.ID where ID is the id specified on the MUI      */
  792. /* object statement.                                                      */
  793. /* Similar approach for accessing the .guide information using the NODE   */
  794. /* option on the object statement.                                        */
  795. /*                                                                        */
  796. /**************************************************************************/
  797.  
  798. help.SQUIT=""""""
  799. help.STEXT=""""""
  800. help.CYCFG="""Wähle Yam Konfiguration Datei"""
  801. help.CYMDR="""Wähle Post Verzeichnis"""
  802. help.CYALL="""Double-click um Eintrag zu bearbeiten.\nIch hoffe du weisst was du tust"""
  803. help.CYFLD="""Benutze Drag-n-drop zum umordnen\nDouble-click um Eintrag zu bearbeiten\nLasse die ersten 4 in Ruhe"""
  804. help.CYMCS="""Bearbeite Eintrag im Haupt Konfiguration\nDrücke Return um aktiven Eintrag zu erneuern"""
  805. help.CYFL1="""Sortiere Anordnung\n0=Neue zuerst\n1=Alte zuerst\n2=Absender\n3=Subject"""
  806. help.CYFL2="""Aktueller Datei name von Ordner\nSie sind ohne Pfad angenommen\nsie sind im gewählten Post Verzeichnis:"""
  807. help.CYFL3="""Ordner name"""
  808. help.CYPR3="""Zeige beide listen"""
  809. help.CYFLI="""Füge neuen Ordner ein"""
  810. help.CYFLX="""Verstecke Ordner Liste\nZeige Haupt Konfig"""
  811. help.CYFLZ="""Lösche Ordner von der Yam Konfiguration"""
  812. help.CYMCI="""Füge neue Linie in Yam Konfiguration ein"""
  813. help.CYMCX="""Verstecke Haupt Konfig\nZeige Ordner Liste"""
  814. help.CYMCZ="""Lösche Linie von der Yam Konfiguration"""
  815. help.CYPR0="""Lade gewählte Konfiguration Datei"""
  816. help.CYPR1="""Speicher gewählte Konfiguration Datei"""
  817. help.CYPR2="""Speicher Konfiguration als neue Datei"""
  818. help.CYPRQ="""Quit ConfigYam"""
  819.  
  820. Return
  821.  
  822.  
  823.  
  824.  
  825.  
  826.